Added ebuild for HandBrake 0.9.4 from gentoo bugzilla

http://bugs.gentoo.org/show_bug.cgi?id=89432

media-video/handbrake/Manifest

@@ -0,0 +1,2 @@
+DIST HandBrake-0.9.4.tar.bz2 1787142 RMD160 a150730cfcb16ee197ba8ec464133e38ab17539e SHA1 91329a83315b7eae0b2b3731a8bf0f2de2a6eb4d SHA256 706b03db4e39446dc47eee2eee298d4aaa3ebd925130e8a84fdc903f231300ee
+EBUILD handbrake-0.9.4.ebuild 1351 RMD160 09565006b83751d779acf2203905ce3fdefa2412 SHA1 171d3a2dd2bd80e50a25cdcd9331e6f019497703 SHA256 689c71010d6efb0cf236b7277f0dc1ab421f82bcd8c9437d4c1b1638fbfb6451

media-video/handbrake/handbrake-0.9.4.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit gnome2-utils
+
+MY_PN="HandBrake"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+DESCRIPTION="Open-source DVD to MPEG-4 converter"
+HOMEPAGE="http://handbrake.fr/"
+SRC_URI="http://handbrake.fr/rotation.php?file=${MY_PN}-${PV}.tar.bz2
+		-> ${MY_PN}-${PV}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="css doc gtk"
+RDEPEND="sys-libs/zlib
+	css? ( media-libs/libdvdcss )
+	gtk? (	>=x11-libs/gtk+-2.8
+			dev-libs/dbus-glib
+			sys-apps/hal
+			net-libs/webkit-gtk
+			x11-libs/libnotify
+			media-libs/gstreamer
+			media-libs/gst-plugins-base
+	)"
+DEPEND="dev-lang/yasm
+	dev-lang/python
+	|| ( net-misc/wget net-misc/curl ) 
+	${RDEPEND}"
+
+src_configure() {
+	# Python configure script doesn't accept all econf flags
+	./configure --force --prefix=/usr \
+		$(use_enable gtk) \
+		|| die "configure failed"
+}
+
+src_compile() {
+	emake -C build || die "failed compiling ${PN}"
+}
+
+src_install() {
+	emake -C build DESTDIR="${D}" install || die "failed installing ${PN}"
+
+	if use doc; then
+		emake -C build doc
+		dodoc AUTHORS CREDITS NEWS THANKS \
+			build/doc/articles/txt/* || die "docs failed"
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}